無料匿名プロキシサイト「ゲッタープロキシ」のプロキシデータを自動抽出

最近の書き込み件数：今日 0件、昨日 0件
未読分：5件

Excel VBAでIEを思いのままに操作できるプログラミング術 Excel 2013/2010/2007/2003対応

近田伸矢, 植木悠二, 上田寛

IEのデータ収集＆自動操作のプログラミング本はこの1冊だけ！IEの起動やポップアップウィンドウ、表示を制御する基本的なコードはもちろん、テキストボックスやラジオボタン、表、ハイパーリンクなどのHTML部品を制御する方法など、自動操作に欠かせないノウハウを丁寧に解説。

Message#5 2014年10月14日(火)15時09分
From: プロキシン

返事削除変更

早速の回答ありがとうございます！

こちらも完璧です！

さきほど、IEのオプション確認したら反映されていました。

大変ありがとうございました＾＾

Message#4 2014年10月14日(火)15時05分
From: 通りすがり

返事削除変更

コマンドプロンプトでやるならレジストリで直接書き換えする方法を使うとか。
コマンドでいえば「reg add」にあたる部分ね。

regコマンドについてはこっちを参照
http://pasofaq.jp/windows/command/reg.htm#nameid1

あと設定方法はこっちを参照
http://support.microsoft.com/kb/2289942/ja

参考事例：reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f

あとはこいつをbatファイルに出力させて

CreateObject("WScript.Shell").Run

で実行させたら完了かな？

以下が設定内容でcells(1,1)がIPアドレスでcells(1,2)がポート番号。

Sub cmd()
Dim targetRange As Range
Dim FSO As Object
Dim i As Long
Dim myTextFile As Object
Dim batFilePath As String

Set FSO = CreateObject("Scripting.FileSystemObject")
'バッチファイルをテンポラリフォルダーに作成して実行
batFilePath = FSO.GetSpecialFolder(2) & "\temp.bat"
Set myTextFile = FSO.CreateTextFile(batFilePath)

cmdstr = "reg add ""HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"" /v ProxyServer /t REG_SZ /d " _
& Cells(1, 1) & ":" & Cells(1, 2) & " /f"

With myTextFile
.writeline cmdstr
.Close
End With
Set FSO = Nothing
CreateObject("WScript.Shell").Run "CMD.EXE /C " & batFilePath, , True
End Sub

Message#3 2014年10月14日(火)14時57分
From: プロキシン

返事削除変更

すごい！できました。

これ今debug.printで設定されていますが、これをセルに貼り付けていけばいいんですよね。

実は、こいつをIEのプロキシサーバーとして自動設定したいと考えています。

コマンドプロンプトで自動設定できないかと思っているんですがどうでしょう？

VBAでいけるもんですか？

こちらも分かりましたら教えてください＞＜

Message#2 2014年10月14日(火)14時42分
From: 通りすがり

返事削除変更

このサイトのログイン画面開くとアンチウィルスソフトが働いて警告表示されるぞ！？
大丈夫か？
まぁ、一応スキャンして、表示させてから見てみると意外と簡単にできたんでのせときます。
これ見てがんばってみて。
一応固まりプログラムはこのサイトのやつを使わせてもらってます。

Sub sample()

Call ieView(objIE, "http://www.getproxy.jp/login")

Call formText(objIE, "username", "★ログインID★")
Call formText(objIE, "loginpass", "★ログインパスワード★")
Call tagClick(objIE, "input", "ログイン")

Call ieNavi(objIE, "http://www.getproxy.jp/japan")

For Each objTag In objIE.document.getElementsByTagName("strong")

If InStr(objTag.outerHTML, ":") > 0 Then

Spoint = InStr(objTag.innerText, ":")
'IPアドレス
Debug.Print Mid(objTag.innerText, 1, Spoint - 1)
'ポート
Debug.Print Mid(objTag.innerText, Spoint + 1, Len(objTag.innerText) - Spoint)

End If
Next

End Sub

Sub ieView(objIE As InternetExplorer, _
　　　　　 urlName As String, _
Optional viewFlg As Boolean = True, _
　　　　　 Optional ieTop As Integer = 0, _
Optional ieLeft As Integer = 0, _
Optional ieWidth As Integer = 600, _
Optional ieHeight As Integer = 800)

　'IEのオブジェクトを作成する
　Set objIE = CreateObject("InternetExplorer.Application")

'IEを表示・非表示
objIE.Visible = viewFlg

　objIE.Top = ieTop　'Y位置
　objIE.Left = ieLeft　'X位置
　objIE.Width = ieWidth　'幅
　objIE.Height = ieHeight　'高さ

'指定したURLのページを表示する
　objIE.Navigate urlName

'IEが完全表示されるまで待機
Call ieCheck(objIE)

End Sub

Sub ieCheck(objIE As InternetExplorer)

　Dim timeOut As Date

　timeOut = Now + TimeSerial(0, 0, 10)

　Do While objIE.Busy = True Or objIE.ReadyState <> 4
　　DoEvents
　　Sleep 100
　　If Now > timeOut Then
　　　objIE.Refresh
　　　timeOut = Now + TimeSerial(0, 0, 10)
　 End If
　Loop

　timeOut = Now + TimeSerial(0, 0, 10)

　Do Until objIE.document.ReadyState = "complete"
　　DoEvents
　　Sleep 100
　　If Now > timeOut Then
　　　objIE.Refresh
　　　timeOut = Now + TimeSerial(0, 0, 10)
　　End If
　Loop

End Sub

Sub formText(objIE As InternetExplorer, _
nameValue As String, _
tagValue As String)

　'テキストボックス・パスワードボックスに値を入力
　For Each objTag In objIE.document.getElementsByTagName("input")

　　If objTag.Name = nameValue Then
　　　objTag.Value = tagValue
　　　Exit For
　　End If

　Next

　'テキストエリアに値を入力
　For Each objTag In objIE.document.getElementsByTagName("textarea")

　　If objTag.Name = nameValue Then
　　　objTag.Value = tagValue
　　　Exit For
　　End If

　Next

End Sub

Sub tagClick(objIE As InternetExplorer, _
tagName As String, _
tagStr As String)

　'タグをクリック
　For Each objTag In objIE.document.getElementsByTagName(tagName)

　　If InStr(objTag.outerHTML, tagStr) > 0 Then

　　　objTag.Click

　　　Call ieCheck(objIE)

　　　Exit For

　　End If

　Next

End Sub

Message#1 2014年10月14日(火)14時34分
From: プロキシン

返事削除変更

下記の無料匿名プロキシサイト「ゲッタープロキシ」のプロキシデータを自動抽出したいと考えています。
VBAを使ってIE起動させるところまではいけるのですが、その後のプロキシデータだけを抽出することができません。
できれば、ログインしたあとにプロキシのＩＰアドレスとポートを分けて抽出したいのですが、どのようにすればよろしいでしょうか？
よろしくお願いします。

http://www.getproxy.jp/japan