開いているページタイトルを取得

<< エクセルVBAでmeta要素のcontent属性値を抽出するサブルーチン  :前の記事

前回は、どのmeta要素のcontent属性値も抽出できるようにmeta要素のcontent属性の値を簡単に抽出できるサブルーチンの作成について解説しました。こちらを利用することで簡単にmeta要素の情報を抽出することができます。今回は、開いているページのタイトルを取得する方法について解説していきます。

ページのタイトルについては、これまで簡単な事例で紹介しましたが、こちらではページのタイトルを取得する方法を詳しく解説していきます。いくつか方法がありますので、どのような道筋でページのタイトルを取得しているか確認してください。

目次

DOM(Document Object Model)とは

DOMとは「Document Object Model」の略称で、html・head・body・p・aなどのHTMLドキュメント要素にアクセスして取得や操作ができる仕組みのことです。

以下はHTMLドキュメントをツリー構造に表したものでDOMツリーと呼ばれます。階層状のツリー構造でHTMLドキュメントを表現します。

DOMツリー

HTML(HyperText Markup Language)とは

HTMLとは「HyperText Markup Language」の略称で、Webページを作成するために開発された言語です。世の中に公開されているWebページのほとんどがHTMLで作成されています。こちらのサイトもHTMLで作成されています。

HTMLは基本的に以下のような構成でできており「<タグ名>★テキスト★</タグ名>」が1つの要素(エレメント)になります。この中の特定の要素に対してデータの取得や操作を行っていきます。

<html>

 <head>

  <title>VBAのIE制御</title>

 </head>

 <body>

  <p>こちらはpタグのテキストです。</p>
  <a href="★リンクURL★">リンクのアンカーテキストです。</a>

 </body>

</html>

タグと要素(エレメント)の違い

HTML言語では、「タグ」と呼ばれる仕組みを利用して構築していきます。以下のイメージを確認すると分かりやすいと思いますが、タグとは「<」と「>」で構成されており、開始タグと終了タグまでの括りで1つの要素を形成します。

タグと要素の違い

具体例で説明するとWebページのタイトルを表す「titleタグ」を利用して開始タグの「<title>」と終了タグの「</title>」で括り、タグの中の文字列が「要素内容」となります。こちらでは「VBAのIE制御入門」の文字列が要素内容となります。

そして、こちらの「開始タグ+要素内容+終了タグ」の全体を「要素」と呼びます。また、別名では「エレメント」と呼ばれますので、どちらも同じ意味であることを理解してください。

利用するサブルーチン・プロパティ・メソッド・VBA関数について

今回利用するサブルーチンプロパティメソッドVBA関数は以下になります。利用方法については処理の解説で行いますが、どのような機能を持っているのか簡単に目を通してください。

  • ieViewサブルーチン
  • ieCheckサブルーチン
  • Documentプロパティとは
  • Allメソッドとは
  • GetElementsByTagNameメソッドとは
  • titleプロパティとは
  • LocationNameプロパティとは
  • Lengthプロパティとは
  • innerTextプロパティとは
  • MsgBox関数とは
  • InStr関数とは

ieViewサブルーチンとは

ieViewサブルーチン指定したURLをInternetExplorerで起動させ、Webページが完全に読み込まれるまで待機処理をするマクロです。

ieView("IEオブジェクト","表示させたいURLの文字列","IE表示・非表示の値[省略可]","Y位置の値[省略可]","X位置の値[省略可]","幅の値[省略可]","高さの値[省略可]")

ieCheckサブルーチンとは

ieCheckサブルーチン指定したInternetExplorerオブジェクトのWebページが完全に読み込まれるまで待機処理をするマクロです。

ieCheck("IEオブジェクト")

Documentプロパティとは

InternetExplorerオブジェクトのDocumentプロパティHTMLドキュメントのオブジェクトを返すプロパティです。これによりHTMLドキュメントを操作することができます。

objIE.document.プロパティ/メソッド

Allプロパティとは

DocumentオブジェクトのAllプロパティHTMLドキュメント内の全ての要素(エレメント)を取得するプロパティです。

objIE.document.All.プロパティ/メソッド
objIE.document.All(添え字).プロパティ/メソッド

GetElementsByTagNameメソッドとは

DocumentオブジェクトのGetElementsByTagNameメソッドHTMLドキュメント内の指定したタグ名の要素オブジェクトのコレクションを返すメソッドです。

objIE.document.GetElementsByTagName("タグ名")(添え字).プロパティ/メソッド

titleプロパティとは

DocumentオブジェクトのtitleプロパティHTMLドキュメントのタイトルを取得するプロパティです。

変数 = objIE.document.title

LocationNameプロパティとは

InternetExplorerオブジェクトのLocationNameプロパティIEウィンドウに表示されているタイトル名を取得するプロパティです。

変数 = objIE.LocationName

Lengthプロパティとは

AllコレクションのLengthプロパティ指定したAllコレクションの全ての要素数を取得するプロパティです。

変数 = objIE.document.All.Length

innerTextプロパティとは

要素オブジェクトのouterHTMLプロパティ指定した要素オブジェクトの要素内のテキスト部分のHTMLコードを取得するプロパティです。

変数 = objIE.document.GetElementsByTagName("タグ名")(添え字).innerText

赤文字がpタグのouterTextの取得範囲になります。

<p>pタグの<span class="colorRed">outerText</span>の取得範囲</p>

MsgBox関数とは

MsgBox関数ダイアログボックスにメッセージとボタンを表示し、どのボタンが押されたかを示す整数型の数値を返します

MsgBox "表示させる文字列"

InStr関数とは

InStr関数ある文字列(string1) の中から指定した文字列 (string2) を検索し、最初に見つかった文字位置(先頭からその位置までの文字数)を返します

変数 = InStr(string1, string2)

開いているページのタイトルを取得する処理の流れ

以下が今回の処理の流れになります。

  • ①変数宣言
  • ②ieViewサブルーチンを利用して指定したURLをIEで起動
  • ③HTMLドキュメントのオブジェクトを取得
  • ④HTMLドキュメント内のtitle要素オブジェクトを取得
  • ⑤title要素オブジェクトの要素タグとその中に含まれるHTMLコードを取得
  • ⑧メッセージボックスに取得したHTMLコードを表示

開いているページのタイトルを取得するサンプルコード

こちらのVBAコードは、IE(InternetExplorer)の開いているページのタイトルを取得するマクロです。

Sub sample()

  Dim objIE As InternetExplorer
  Dim i As Integer

  'IE(InternetExplorer)で本サイトを起動する
  Call ieView(objIE, "http://www.vba-ie.net/")


  '①全要素からtitleタグを探しタイトルを取得する方法
  For i = 0 To objIE.document.all.length - 1

    If InStr(objIE.document.all(i).outerHTML, "<title>") = 1 Then
    
        MsgBox "方法① : " & objIE.document.all(i).innerText

        Exit For
        
    End If
  
  Next i
  
  '②tagsメソッドからタイトルを取得する方法
  MsgBox "方法② : " & objIE.document.all.tags("title")(0).innerText

  '③getElementsByTagNameメソッドからタイトルを取得する方法
  MsgBox "方法③ : " & objIE.document.getElementsByTagName("title")(0).innerText
  
  '④titleプロパティからタイトルを取得する方法
  MsgBox "方法④ : " & objIE.document.title
  
  '⑤LocationNameプロパティからタイトルを取得する方法
  MsgBox "方法⑤ : " & objIE.LocationName

End Sub

処理対象のtaitle要素のHTMLコード

<title>VBAのIE制御入門 | IE操作の自動化</title>

解説

Sub sample()

  Dim objIE  As InternetExplorer
  Dim i As Integer

こちらはSubステートメント引数の設定がないsampleプロシージャになります。 まずは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objIEに「InternetExplorer型」を、変数iに「整数型(Integer)」を変数宣言しています。

  'IE(InternetExplorer)で本サイトを起動する
  Call ieView(objIE, "http://www.vba-ie.net/")

次に他のプロシージャを呼び出すCallステートメントを利用してieViewサブルーチンを呼び出しています。第一引数にはオブジェクト変数の「objIE」を第二引数には表示させるURLの「http://www.vba-ie.net/」を設定しています。これによりInternetExplorerで本サイトのトップページが表示されます。

  '①全要素からtitleタグを探しタイトルを取得する方法
  For i = 0 To objIE.document.all.length - 1

    If InStr(objIE.document.all(i).outerHTML, "<title>") = 1 Then
    
        MsgBox "方法① : " & objIE.document.all(i).innerText
        Exit For
        
    End If
  
  Next i

ここからはallプロパティを利用してtitle要素を取得する処理になります。以下は理解しやすい様にVBAコードとキーワードの関連性を列挙したものです。あくまで関連性ですので必ずしも「=(イコール)」ではありません。

  • 【objIE.document.all.length】
  • 【objIE.document.all(i).outerHTML】
  • 【objIE.document.all(i).innerText】
  • objIE = InternetExplorerオブジェクト
  • document = HTMLドキュメントのオブジェクト(Documentプロパティ)
  • all = Documentオブジェクトのすべての要素(allコレクション)
  • all(i) = allコレクション内のi番目の要素オブジェクト
  • length = allコレクションの要素(エレメント)数
  • outerHTML = all(i)の要素タグとそのタグに含まれるHTMLコード
  • innerText = all(i)の要素タグ内に含まれるテキスト(要素内容)

こちらでは、指定した回数同じ処理を繰り返すFor~Nextステートメントを利用して全ての要素の数だけループ処理を行っています。ループ内の処理はIf~Then~Elseステートメントを利用してループ対象時の要素がtitle要素の場合にタイトルを抽出する内容となっています。

まず、InternetExplorerオブジェクトのdocumentプロパティを利用してHTMLドキュメントのオブジェクト(Documentオブジェクト)を取得します。

次にDocumentオブジェクトのAllコレクションを利用してHTMLドキュメントのすべての要素を取得します。そして、Allコレクションのlengthプロパティを利用してHTMLドキュメントの要素数を取得します。こちらの要素数がループ処理の回数になりますが、「0」から始まるため1引いた数値を設定しています。

ループ処理内の処理でIf~Then~ElseステートメントInStr関数を利用してループ対象時の要素が「<title>」の場合にその要素のテキスト(要素内容)を抽出します。この抽出されたテキスト(要素内容)がタイトル名となります。

取得したデータはMsgBox関数の引数に設定しており、以下のようにメッセージボックスが表示されますので、処理を実行して確認してください。

IE(InternetExplorer)のタイトルを取得する
    '②tagsメソッドからタイトルを取得する方法
  MsgBox "方法② : " & objIE.document.all.tags("title")(0).innerText

こちらの処理はAllコレクションのtagsメソッドを利用してタイトルを取得する処理になります。tagsメソッドには「title」を設定していますのでtitle要素のコレクションを取得します。titleタグはページ内に1度しか記述されませんが、配列として格納されているため添え字が必要ですので、1番目の要素の「0」を設定します。

title要素オブジェクトを取得したら、innerTextプロパティでtilteタグ内のテキスト(要素内容)つまりタイトル名を抽出します。

  '③getElementsByTagNameメソッドからタイトルを取得する方法
  MsgBox "方法③ : " & objIE.document.getElementsByTagName("title")(0).innerText

こちらの処理はgetElementsByTagNameメソッドを利用してタイトルを取得する処理になります。getElementsByTagNameメソッドには「title」を設定していますのでtitle要素のコレクションを取得します。こちらも先ほどと同様に添え字の「0」を設定します。

title要素オブジェクトを取得したら、innerTextプロパティタイトル名を抽出します。

  '④titleプロパティからタイトルを取得する方法
  MsgBox "方法④ : " & objIE.document.title

こちらの処理はdocumentオブジェクトのtitleプロパティを利用してタイトルを取得する処理になります。こちらはtitleプロパティを設定することでHTMLドキュメントのタイトル名を抽出します。

  '⑤LocationNameプロパティからタイトルを取得する方法
  MsgBox "方法⑤ : " & objIE.LocationName

こちらの処理はInternetExplorerオブジェクトのLocationNameプロパティを利用してタイトルを取得する処理になります。こちらはLocationNameプロパティを設定することでIEウィンドウに表示されているページのタイトル名を抽出します。

documentオブジェクトのtitleプロパティとInternetExplorerオブジェクトのLocationNameプロパティは同じような機能ですが、違いがありますので少し解説していきます。

titleプロパティとLocationNameプロパティの違いについて

titleプロパティLocationNameプロパティの違いについてですが、DocumentオブジェクトのtitleプロパティHTMLドキュメントのタイトルを返します。

例えば、フレームのあるページの場合、titleプロパティでは開いているページのタイトルだけでなく、フレームで設定されている複数のページのタイトルも取得することができます。

以下はフレームのURLを取得する事例になりますので、確認してください。

Sub sampaale()

  Dim objIE  As InternetExplorer
  Dim objFrame As Object

  'テスト用フレームページを表示
  Call ieView(objIE, "http://www.vba-ie.net/code/test2.html")

  'フレーム情報取得
  Set objFrame = objIE.document.frames

  '①開いているページのタイトル
  MsgBox "開いているページのURL: " & objIE.document.title
 
  '②frame1ページのタイトル
  MsgBox "frame1のURL: " & objFrame("frame1").document.title

  '③frame2ページのタイトル
  MsgBox "frame2のURL: " & objFrame("frame2").document.title

End Sub

詳しい処理内容については割愛しますが、「objIE.document.title」では開いているページのタイトルを取得し、「objFrame("frame1").document.title」と「objFrame("frame2").document.title」はフレームのタイトルを取得しています。以下は処理結果になります。

IE(InternetExplorer)のtitleプロパティの結果

フレームのタイトルをInternetExplorerオブジェクトのLocationNameプロパティで取得したい場合は一旦フレームのURLを取得し、そのページを単独で開いてからタイトルを取得するといった手間がかかりますので、フレームのタイトルを取得する場合はDocumentオブジェクトのtitleプロパティを利用するようにしましょう。

次に開いているページのタイトルを取得する場合どの方法が一番有効かについてですが、どの方法を利用しても同じ結果なのでどれを選択しても問題ありません。ただし、処理数が多い場合はなるべく処理速度の速いものを利用した方が早く済みます。そこで、どの処理が一番速いのかを検証してみました。

タイトル取得処理の計測結果

以下はそれぞれの処理を5000回繰り返し処理をした時間を計測したものです。こちらの結果を見ると処理④のDocumentオブジェクトのtitleプロパティが一番処理が速いことになります。

webスクレイピングを行う以外はどれを選んでも大差はありませんが、webスクレイピングで処理回数が多い場合は、titleプロパティでの処理がオススメです。

  • 処理①・・・全要素からtitleタグを探しタイトルを取得
  • 処理②・・・tagsメソッドからタイトルを取得
  • 処理③・・・getElementsByTagNameメソッドからタイトルを取得
  • 処理④・・・titleプロパティからタイトルを取得
  • 処理⑤・・・LocationNameプロパティからタイトルを取得
回数・処理処理①処理②処理③処理④処理⑤
1回目60.3906秒15.3594秒13.7695秒10.5195秒11.0039秒
2回目53.9688秒16.3477秒14.2227秒10.8984秒11.4141秒
3回目61.0153秒17.0313秒14.0156秒10.7539秒11.5121秒
4回目57.0352秒17.1634秒14.0231秒10.9219秒11.8789秒
5回目60.0184秒16.9587秒14.2383秒10.8359秒11.0586秒
平均58.4856秒16.5721秒14.0538秒10.7859秒11.3735秒

まとめ

今回は、5つの方法で開いているページのタイトルを取得する方法について解説しました。最後にどの処理が一番速いかを計測しましたが、処理回数が多い場合はDocumentオブジェクトのtitleプロパティが一番早いことが分かりました。次回は、開いているページのURLを取得する方法について解説していきます。

次の記事: エクセルVBAでページのURLを取得する >>

Excel VBAでIEを思いのままに操作できるプログラミング術 Excel 2013/2010/2007/2003対応

近田 伸矢, 植木 悠二, 上田 寛

IEのデータ収集&自動操作のプログラミング本はこの1冊だけ!IEの起動やポップアップウィンドウ、表示を制御する基本的なコードはもちろん、テキストボックスやラジオボタン、表、ハイパーリンクなどのHTML部品を制御する方法など、自動操作に欠かせないノウハウを丁寧に解説。

  • このエントリーをはてなブックマークに追加
VBAのIE制御についてのQ&A掲示板

↑エクセルVBAのIE(InternetExplorer)操作で分からない事があればこちらの掲示板よりご質問ください^^

ExcelのVBA初心者入門

↑こちらはExcelのVBAをマスターできるよう初心者向けのエクセルVBA入門コンテンツになります^^

VBAのIE制御入門RSS

RSSフィードを登録すると最新記事を受け取ることができます。

VBAIE操作のスカイプレッスン

VBAでIE(InternetExplorer)制御の準備

【ダウンロード】IE操作に便利なツール

こちらでは、これまでに紹介したIE(InternetExplorer)操作で便利な機能をツール化しています。無償でダウンロードできますので、目的に合わせたご利用ください。

IEオブジェクトのメソッド・プロパティ

こちらでは、IE(InternetExplorer)オブジェクトのメソッド・プロパティをまとめています。

IE操作に利用されているVBA関数

こちらでは、エクセルVBAのIE(InternetExplorer)操作で利用されたVBA関数をまとめています。

IE操作に利用されているステートメント

こちらでは、エクセルVBAのIE(InternetExplorer)操作で利用されたステートメントをまとめています。ExcelのVBAで基本的な部分になりますので、しっかり理解しましょう。

IE(InternetExplorer)制御のVBAコード

こちらでは、これまでに作成したIE(InternetExplorer)操作で役立つサブルーチンをまとめています。
全てをコピーする必要はありませんが、目的に合わせたサブルーチンをご利用ください。