VBAのIE操作でヤフーファイナンスの検索後にタイトルを取得するには

yahooファイナンスの詳細ページのHTMLソースを見ると企業名はh1タグ、企業コードはdtタグでくくられていたので、添え字を付け加えて直接取得する方法にしてみました。

以下をご確認ください。

Sub sample()

Dim objIE As InternetExplorer

Call ieView(objIE, "http://finance.yahoo.co.jp/")

Call formText(objIE, "query", "ホテルオークラ")
Call tagClick(objIE, "input", "株価検索")

'企業名
Debug.Print objIE.document.body.getElementsByTagName("h1")(0).innerText

'企業コード
Debug.Print objIE.document.body.getElementsByTagName("dt")(0).innerText

End Sub

Sub ieView(objIE As InternetExplorer, _
　　　　　 urlName As String, _
Optional viewFlg As Boolean = True, _
　　　　　 Optional ieTop As Integer = 0, _
Optional ieLeft As Integer = 0, _
Optional ieWidth As Integer = 600, _
Optional ieHeight As Integer = 800)

　'IEのオブジェクトを作成する
　Set objIE = CreateObject("InternetExplorer.Application")

'IEを表示・非表示
objIE.Visible = viewFlg

　objIE.Top = ieTop　'Y位置
　objIE.Left = ieLeft　'X位置
　objIE.Width = ieWidth　'幅
　objIE.Height = ieHeight　'高さ

'指定したURLのページを表示する
　objIE.Navigate urlName

'IEが完全表示されるまで待機
Call ieCheck(objIE)

End Sub

Sub ieCheck(objIE As InternetExplorer)

　Dim timeOut As Date

　timeOut = Now + TimeSerial(0, 0, 10)

　Do While objIE.Busy = True Or objIE.ReadyState <> 4
　　DoEvents
　　Sleep 100
　　If Now > timeOut Then
　　　objIE.Refresh
　　　timeOut = Now + TimeSerial(0, 0, 10)
　 End If
　Loop

　timeOut = Now + TimeSerial(0, 0, 10)

　Do Until objIE.document.ReadyState = "complete"
　　DoEvents
　　Sleep 100
　　If Now > timeOut Then
　　　objIE.Refresh
　　　timeOut = Now + TimeSerial(0, 0, 10)
　　End If
　Loop

End Sub

Sub formText(objIE As InternetExplorer, _
nameValue As String, _
tagValue As String)

　'テキストボックス・パスワードボックスに値を入力
　For Each objTag In objIE.document.getElementsByTagName("input")

　　If objTag.Name = nameValue Then
　　　objTag.Value = tagValue
　　　Exit For
　　End If

　Next

　'テキストエリアに値を入力
　For Each objTag In objIE.document.getElementsByTagName("textarea")

　　If objTag.Name = nameValue Then
　　　objTag.Value = tagValue
　　　Exit For
　　End If

　Next

End Sub

Sub tagClick(objIE As InternetExplorer, _
tagName As String, _
tagStr As String)

　'タグをクリック
　For Each objTag In objIE.document.getElementsByTagName(tagName)

　　If InStr(objTag.outerHTML, tagStr) > 0 Then

　　　objTag.Click

　　　Call ieCheck(objIE)

　　　Exit For

　　End If

　Next

End Sub