VBAのIE制御

Function tagValue(objIE As InternetExplorer, _
                 methodType As String, _
                 elementName As String, _
                 keywords As String, _
                 valueType As String) As String
 
  Dim objDoc As Object, myDoc As Object

  Select Case methodType

    Case "id"

      Set objDoc = objIE.document.getElementById(elementName)
        
    Case "name"
  
      Set objDoc = objIE.document.getElementsByName(elementName)
    
    Case "class"
  
      Set objDoc = objIE.document.getElementsByClassName(elementName)
    
    Case "tag"

      Set objDoc = objIE.document.getElementsByTagName(elementName)

  End Select

 
  For Each myDoc In objDoc

    With myDoc

      If InStr(.outerHTML, keywords) > 0 Then
    
        Select Case valueType

          Case "innerHTML"

            tagValue = .innerHTML

          Case "innerText"
             
            tagValue = .innerText
      
          Case "outerHTML"
 
            tagValue = .outerHTML

          Case "outerText"

            tagValue = .outerText

        End Select

        Exit For

      End If
    
    End With

  Next

End Function

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは戻り値を返すFunctionステートメントに引数を5つ設定しているclassValueサブルーチンになります。こちらの構文と引数の内容は以下になります。尚、引数はすべて参照渡しで渡されます。

引数objIEは必須項目で、文書ドキュメントを抽出するnternetExplorerオブジェクトを指定します。InternetExplorerオブジェクトを引数に設定することで、複数のオブジェクトを処理することができます。

引数methodTypeは必須項目で、要素を抽出するメソッドのタイプを文字列で指定します。getElementsByNameメソッドの場合は「name」を、getElementsByClassNameメソッドの場合は「class」を、getElementsByTagNameメソッドの場合は「tag」で指定します。

引数elementNameは必須項目で、メソッドの引数を文字列で指定します。引数methodTypeに「name」を指定した場合はid名を、「class」を指定した場合はclass名を「tag」を指定した場合はタグ名を指定します。

引数keywordsは必須項目で、要素内の一意のキーワードを文字列で指定します。「要素内の一意のキーワード」というのは、抽出したい要素データ内で他とまったく被らないキーワードのことを指します。

例えば下記の事例で販売価格を抽出したい場合、「円(税込)」というキーワードは他では利用されていないキーワードですので、こちらを「一意のキーワード」と判断します。

こちらの詳細については、「文書ドキュメント取得の処理の考え方」を確認してください。

<table>
<tr>商品名</th><td>商品A</td></tr>
<tr>販売価格</th><td>1,500円(税込)</td></tr>
<tr>カラー</th><td>ブラック、ホワイト、レッド</td></tr>
<tr>サイズ</th><td>32*25cm</td></tr>
</table>

引数valueTypeは必須項目で、データ取得のプロパティ名を文字列で指定します。データ取得のプロパティは「innerHTML」「innerText」「outerHTML」「outerText」の4つになります。

詳細については、「HTMLコードを取得する」を確認してください。

Dim objDoc As Object, myDoc As Object

※ドラッグ(スワイプ)すると全体を確認できます。

こちらは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objDoc,myDocに「オブジェクト型(Object)」を変数宣言しています。

先に説明すると、データ型はオブジェクト型(Object)を利用せず、より具体的なデータ型を宣言するほうがよいとされています。理由としては、補助入力機能など利便性のよさなどが挙げられます。

こちらについては本来であれば、「HTMLParaElement型」または「HTMLDocument型」などを指定するのがよいのでしょうか処理速度の観点からいうと必ずしもよいというわけではなりません。

他にもいくつか検証したのですが、以下のようにHTML関連のデータ型を選択した場合とオブジェクト型(Object)ではどれもオブジェクト型(Object)を選択した方が処理速度が速い結果となりました。

ですので、こちらで解説している内容のほとんどはオブジェクト型(Object)を選択しています。特に変更してもらっても問題ありませんので、自由に変更してください。

  Select Case methodType

    Case "name"
  
      Set objDoc = objIE.document.getElementsByName(elementName)
    
    Case "class"
  
      Set objDoc = objIE.document.getElementsByClassName(elementName)
    
    Case "tag"

      Set objDoc = objIE.document.getElementsByTagName(elementName)

  End Select

※ドラッグ(スワイプ)すると全体を確認できます。

こちらでは、複数の条件分岐を設定するSelect Caseステートメントを利用して引数methodTypeの設定値で条件分岐させています。

こちらでは、getElementsByName・getElementsByClassName・getElementsByTagNameメソッドの中からどのメソッドを利用して抽出する要素を取得するかを選択しています。

こちらの条件分岐は極力処理速度の遅いgetElementsByTagNameメソッドを利用しないための処理です。一意のキーワードの要素にname・class属性が設定されている場合は、getElementsByName・getElementsByClassNameメソッドを利用するようにしましょう。

  For Each myDoc In objDoc

   （処理省略）

  Next

※ドラッグ(スワイプ)すると全体を確認できます。

こちらでは、For Each～Nextステートメントのコレクションに設定し、オブジェクト変数objDocを設定しています。これにより先ほど取得した要素数だけループ処理を行っています。

    With myDoc

      If InStr(.outerHTML, keywords) > 0 Then
    
        Select Case valueType

          Case "innerHTML"

            tagValue = .innerHTML

          Case "innerText"
             
            tagValue = .innerText
      
          Case "outerHTML"
 
            tagValue = .outerHTML

          Case "outerText"

            tagValue = .outerText

        End Select

        Exit For

      End If
    
    End With

※ドラッグ(スワイプ)すると全体を確認できます。

こちらではまず、Withステートメントのオブジェクト名に「myDoc」を設定しています。こちらは先ほど取得した要素コレクションのオブジェクトになります。

次にIf～Then～Elseステートメントを利用して要素内の文書ドキュメントに引数keywordsが含まれている場合に要素を抽出します。

「一意のキーワード」が含まれているかの確認は、指定したキーワードで最初に見つかった文字位置を返すInStr関数を利用しています。キーワードが含まれている場合は必ず「0」以上の値を返すので、比較演算子を利用して「0」以上の場合を条件式としています。

そして、取得した値を戻り値tagValueに代入演算子で格納したら処理が完了します。

↑VBAのIE操作で分からない事があればこちらの掲示板よりご質問ください。

↑こちらはVBAをマスターできるよう初心者向けのエクセルVBA入門コンテンツになります。

目次