VBAでファイルをダウンロードするためのサブルーチン「fileDL」

VBAのIE(InternetExplorer)制御で画像データをはじめ、pdfファイル、エクセル・ワードファイルなどをダウンロードして保存数サブルーチンです。

「fileDLサブルーチン」の詳しい解説については、以下より確認してください。

データ抽出やインターフェースの自動化にしても必ず最初は指定したURLをIEで起動させるところから始まります。 こちらの処理は何度も利用されるプログラムですので、そのような処理をサブルーチン化させると色々なメリットが生まれます。ここでは、そのようなサブルーチン化のメリットも含めて解説しています。

サブルーチンとは

サブルーチンとは、プログラム処理の中で繰り返し利用されるルーチン作業をモジュール化(部品化)してまとめたものになります。また、呼び出す側をメインルーチンと呼ぶのに対して「サブルーチン」と呼ばれます。

メリット

繰り返し利用されるルーチン作業をモジュール化(部品化)することで、同じ処理のプログラムを何度も書く手間が省け、プログラムも全体的に見やすくなります。これによりプログラムソースの可読性や保守性を高く保つことができます。

関連性の高いサブルーチン

Declare Function URLDownloadToFile Lib "urlmon" Alias _
    "URLDownloadToFileA" (ByVal pCaller As Long, _
    ByVal szURL As String, _
    ByVal szFileName As String, _
    ByVal dwReserved As Long, _
    ByVal lpfnCB As Long) As Long

Declare Function DeleteUrlCacheEntry Lib "wininet" _
    Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long

Sub fileDL(objIE As InternetExplorer, _
      tagStr As String, _
      saveFolder As String, _
      Optional fileDLType As String = "img")

 Dim fileURL As String, fileName As String, savePath As String
 Dim cacheDel As Long, result As Long
    
 'ファイルURL取得
 If fileDLType = "img" Then
  fileURL = srcValue(objIE, tagStr)
 Else
  fileURL = linkValue(objIE, tagStr)
 End If
    
  'ファイルチェック
  If fileURL = "" Then
    MsgBox "ファイルURLを取得できませんでした。"
    Exit Sub
  End If
    
 'ファイル名
 fileName = Mid(fileURL, InStrRev(fileURL, "/") + 1)
    
 'ファイル保存先(+画像ファイル名)
 savePath = ActiveWorkbook.Path & "\" & saveFolder & "\" & fileName
    
 'キャッシュクリア
 cacheDel = DeleteUrlCacheEntry(fileURL)
    
 'ファイルをダウンロード
 result = URLDownloadToFile(0, fileURL, savePath, 0, 0)
    
 If result <> 0 Then
  MsgBox "ダウンロードに失敗しました。"
 End If

End Sub

それでは、VBAコードを1つずつ説明していきます。

Declare Function URLDownloadToFile Lib "urlmon" Alias _
    "URLDownloadToFileA" (ByVal pCaller As Long, _
    ByVal szURL As String, _
    ByVal szFileName As String, _
    ByVal dwReserved As Long, _
    ByVal lpfnCB As Long) As Long

まず、画像をダウンロードするWindows APIのURLDownloadToFile関数を使用できるようにAPIの宣言をします。宣言する場合は、宣言セクション内に記述します。宣言ステートメントは、最初のプロシージャ宣言の前に配置する必要がありますので、一番上に記述してください。

Declare Function DeleteUrlCacheEntry Lib "wininet" _
    Alias "DeleteUrlCacheEntryA" (ByVal lpszUrlName As String) As Long

次に画像のキャッシュを削除するWindows APIのDeleteUrlCacheEntry関数を使用できるようにこちらもAPIの宣言をします。画像をダウンロードする際にキャッシュが存在するとキャッシュから読み込むので、最新の画像をダウンロードするためにキャッシュを削除してからダウンロードを行います。

Sub fileDL(objIE As InternetExplorer, _
      tagStr As String, _
      saveFolder As String, _
      Optional fileDLType As String = "img")

こちらはSubステートメントに引数を4つ設定しているfileDLサブルーチンになります。こちらの構文と引数の内容は以下になります。尚、引数はすべて参照渡しで渡されます。

fileDL("IEオブジェクト","タグ内の一意のキーワード文字列","ファイル保存先のフォルダ文字列","ダウンロードするファイルの種類文字列[省略可]")
構文fileDL(objIE,tagStr,saveFolder[,fileDLType])
引数名データ型内容値の事例初期値省略
objIEInternetExplorerIEオブジェクトobjIE,objIE2×
tagStrStringタグ内の一意のキーワード文字列"vbaproject"×
saveFolderStringファイル保存先のフォルダ文字列"image"×
fileDLTypeStringダウンロードするファイルの種類文字列"img",
"pfd",
"xls",
"doc"
"img"

引数objIEは必須項目で、文書ドキュメントを抽出するnternetExplorerオブジェクトを指定します。InternetExplorerオブジェクトを引数に設定することで、複数のオブジェクトを処理することができます。

引数tagStrは必須項目で、抽出するタグ内の一意のキーワードを文字列で指定します。「抽出するタグ内の一意のキーワード」というのは、ダウンロードするファイルが設定されているタグ内で他とまったく被らないキーワードのことを指します。

例えば下記の場合、「こちらは一意のアンカーテキストです。」というキーワードは他では利用されていないキーワードですので、こちらを「一意のキーワード」と判断します。他にも「アンカーテキストです。」「です。」も一意のキーワードとして利用することもできます。

こちらの詳細については、「文書ドキュメント取得の処理の考え方」を確認してください。

<a href="#a1">こちらは一意のアンカーテキストではありません。</a>
<a href="#a2">こちらは一意のアンカーテキストではありません。</a>
<a href="#a3">こちらは一意のアンカーテキストです。</a>
<a href="#a4">こちらは一意のアンカーテキストではありません。</a>
<a href="#a5">こちらは一意のアンカーテキストではありません。</a>

引数saveFolderは必須項目で、ファイル保存先のフォルダ文字列を指定します。保存先は処理を実行するエクセルファイルと同じディレクトリで「saveFolder」で指定したフォルダ内に保存されます。

引数fileDLTypeは任意項目で、ファイルの種類を指定します。初期状態では「img」が設定されていますので、画像をダウンロードする場合は設定不要ですが、pdfファイルなど画像ファイル以外の場合は、拡張子でもなんでもいいので分かりやすいキーワードで指定してください。

こちらの引数fileDLTypeはファイルのURLを取得するための条件分岐で利用されます。「img」の場合はsrcValueサブルーチンimg要素から画像URLを抽出し、そのほかの場合はlinkValueサブルーチンa要素からファイルURLを抽出します。

  Dim fileURL As String, fileName As String, savePath As String
 Dim cacheDel As Long, result As Long

こちらは、変数宣言でメモリ領域を割り当てるDimステートメントを利用してオブジェクト変数objIEInternetExplorer型を、変数imgURL・fileName・savePathに「文字列型(String)」を、変数cacheDel・resultに「長整数型(Long)」を変数宣言しています。

URLDownloadToFile関数を利用する際によくあるトラブルが変数宣言の間違いです。戻り値の変数に整数型(Integer)を宣言している場合は「オーバーフローしました。」とエラーになります。理由としては、ダウンロードが失敗した場合の戻り値は「-2146697210 」となるため、整数型では許容範囲を超えるためです。

ですので、URLDownloadToFile関数DeleteUrlCacheEntry関数の戻り値の変数には、長整数型を宣言しています。

If fileDLType = "img" Then
 fileURL = srcValue(objIE, tagStr)
Else
 fileURL = linkValue(objIE, tagStr)
End If

こちらは引数fileDLTypeで指定されたファイルの種類を、条件分岐ができるIf~Then~Elseステートメントを利用してチェックしています。「img」の場合はsrcValueサブルーチン画像URLを取得し、それ以外の場合はlinkValueサブルーチンファイルURLを取得しています。

  'ファイルチェック
  If fileURL = "" Then
    MsgBox "ファイルURLを取得できませんでした。"
    Exit Sub
  End If

こちらもIf~Then~Elseステートメントを利用してファイルURLが取得されているかどうかチェックを行い、取得できなかった場合はExit Subステートメントで処理を終了させています。

 'ファイル名
 fileName = Mid(fileURL, InStrRev(fileURL, "/") + 1)

こちらはMid関数InStrRev関数を利用してファイルURLからファイル名の部分だけを抽出しています。

InStrRev関数は文字列の中から指定した文字列が後ろから何番目にあるかを返す文字列処理関数です。指定した文字列は「/(スラッシュ)」になりますので、一番後ろの「/(スラッシュ)」の位置を返します。

Mid関数は文字列から指定した文字数分の文字列を返す関数です。画像ファイル名は、一番後ろの「/(スラッシュ)」の位置から右側部分になりますので、抽出開始位置は「/(スラッシュ)」の位置から「+1」としています。これにより画像ファイル名のみを抽出することができます。

そして、抽出したファイル名を変数fileNameに格納します。

'ファイル保存先(+画像ファイル名)
 savePath = ActiveWorkbook.Path & "\" & saveFolder & "\" & fileName

こちらはファイルの保存先(+ファイル名)の設定ですが、実行ファイルと同じディレクトリにある変数saveFolderのフォルダへ格納します。こちらを利用する場合は事前にフォルダを作成する必要がありますので作成しておいてください。

また、こちらはURLDownloadToFile関数で利用する引数になりますが、同じ名前のファイルが存在したい場合は、上書き保存されますので注意が必要です。

cacheDel = DeleteUrlCacheEntry(fileURL)

こちらはWindows APIのDeleteUrlCacheEntry関数を利用してキャッシュをクリアしています。引数には、変数fileURLを設定します。

こちらの処理はキャッシュがあった場合、古いファイルを誤ってダウンロードしてしまう可能性もあるため、ファイルをダウンロードする前に一旦キャッシュを削除しています。

result = URLDownloadToFile(0, fileURL, savePath, 0, 0)

こちらはURLDownloadToFile関数を利用して画像をダウンロードする処理になります。引数はいくつかありますが、第二引数に「ファイルURL」を第三引数に「画像の保存先(+画像ファイル名)」を設定します。これでファイルをダウンロードすることができます。

If result <> 0 Then
 MsgBox "ダウンロードに失敗しました。"
End If

こちらは正常にダウンロードされたかのチェック部分になります。URLDownloadToFile関数はダウンロードに成功すると「0」を返すので、If~Then~Elseステートメントを利用して変数resultが「0以外(ダウンロード失敗)」の場合は「ダウンロードに失敗しました。」と表示されます。